Appendix 1. Summary of Banding Data Used in Hierarchical Bayes Stopover Models

Appendix 1. – Summary of banding data used in hierarchical Bayes stopover models

Total annual number of individuals banded at Long Point Bird Observatory between 1987-2007 that were included in each of the species- and season-specific mark-recapture datasets, and the average annual total for each; data from 1993 and 2003 were excluded from analyses (na).

Species / Season / 1987 / 1988 / 1989 / 1990 / 1991 / 1992 / 1993 / 1994 / 1995 / 1996 / 1997 / 1998 / 1999 / 2000 / 2001 / 2003 / 2002 / 2004 / 2005 / 2006 / 2007 / Average
Temperate migrants
HETH / spring / 187 / 90 / 220 / 159 / 114 / 73 / NA / 84 / 90 / 102 / 102 / 151 / 157 / 161 / 131 / NA / 113 / 110 / 132 / 193 / 147 / 132
fall / 168 / 196 / 183 / 125 / 107 / 99 / NA / 112 / 316 / 138 / 155 / 223 / 149 / 202 / 230 / NA / 170 / 132 / 147 / 211 / 93 / 166
RCKI / spring / 471 / 218 / 332 / 382 / 461 / 116 / NA / 281 / 227 / 152 / 147 / 256 / 211 / 290 / 158 / NA / 235 / 179 / 214 / 276 / 250 / 256
fall / 690 / 450 / 483 / 853 / 519 / 285 / NA / 341 / 590 / 276 / 329 / 379 / 429 / 731 / 487 / NA / 444 / 510 / 700 / 695 / 413 / 505
DEJU / spring / 48 / 72 / 92 / 74 / 177 / 134 / NA / 76 / 37 / 40 / 134 / 69 / 49 / 21 / 90 / NA / 53 / 43 / 90 / 55 / 57 / 74
fall / 59 / 53 / 78 / 165 / 94 / 58 / NA / 74 / 46 / 99 / 121 / 107 / 72 / 150 / 80 / NA / 152 / 72 / 97 / 289 / 105 / 104
WTSP / spring / 362 / 210 / 298 / 309 / 442 / 436 / NA / 323 / 216 / 176 / 299 / 379 / 371 / 498 / 422 / NA / 533 / 728 / 379 / 484 / 828 / 405
fall / 123 / 145 / 191 / 358 / 167 / 172 / NA / 137 / 202 / 201 / 203 / 169 / 139 / 327 / 378 / NA / 356 / 292 / 402 / 428 / 355 / 250
Tropical migrants
AMRE / spring / 33 / 72 / 60 / 40 / 54 / 76 / NA / 41 / 54 / 47 / 94 / 44 / 63 / 59 / 33 / NA / 57 / 35 / 62 / 34 / 69 / 54
fall / 90 / 47 / 68 / 62 / 88 / 51 / NA / 101 / 75 / 76 / 69 / 115 / 46 / 81 / 64 / NA / 70 / 50 / 43 / 110 / 98 / 74
BTBW / spring / 22 / 39 / 27 / 18 / 29 / 40 / NA / 19 / 66 / 44 / 55 / 21 / 75 / 61 / 41 / NA / 30 / 31 / 47 / 31 / 53 / 39
fall / 52 / 32 / 42 / 47 / 55 / 24 / NA / 33 / 100 / 59 / 40 / 94 / 85 / 54 / 77 / NA / 95 / 69 / 66 / 94 / 81 / 63
MAWA / spring / 408 / 274 / 229 / 280 / 232 / 209 / NA / 141 / 283 / 175 / 268 / 280 / 323 / 333 / 304 / NA / 176 / 175 / 273 / 297 / 295 / 261
fall / 158 / 101 / 138 / 130 / 201 / 85 / NA / 120 / 200 / 157 / 102 / 129 / 144 / 113 / 129 / NA / 176 / 109 / 90 / 225 / 138 / 139
SWTH / spring / 11 / 69 / 43 / 49 / 39 / 61 / NA / 32 / 41 / 49 / 74 / 54 / 49 / 61 / 59 / NA / 44 / 55 / 61 / 64 / 83 / 53
fall / 148 / 216 / 210 / 112 / 196 / 103 / NA / 58 / 176 / 75 / 144 / 180 / 121 / 145 / 121 / NA / 127 / 84 / 329 / 145 / 242 / 154

Appendix 2. – BUGS code for the migratory stopover model with a linear covariate

BUGS code for a hierarchical stopover-decision model with annual climate covariate { phi[NAO*k] p[y*k] Psi[y*k] } where parameters are constrained for all but one state (the “non-transient state”, see text and Schaub et al. 2004). Note that to be consistent with standard mark-recapture notation and other related models, this code uses phi for the ’survival’ parameter (denoted ε in the manuscript), and Psi for the ’transition’ parameter (denoted τ in the manuscript). Parameter phi is constrained to vary as a linear function of annual NAO index, while parameters p and Psi are all allowed to vary across years (y) and among states (k). Within the multi-state stopover model encounter history data, individuals were assigned a value of 1 (initial state) at their first encounter, and 2 (non-transient state) at every subsequent encounter; all other days were denoted by a 4 (no observation for that individual; denoted by 0 in traditional mark-recapture), as individuals in state 3 (transients) are by definition unobservable following initial capture. For further details on parameter definitions, model structure and development, and notation for the more general model (without a climate covariate), see Calvert et al. (2009b).

# model { phi[yk] p[NAO*k] Psi[yk] } for K=3 (dead/unobserved =4), with stopover constraints

# data file requirements: K (number of states), Bidx[y] (limit of data for each year y), idx[i] (beginning and end-point of encounter histories for each individual i), z[t] (vector of true states at each time t), w[t] (observation indication vector at each time t), c[i] (initial capture date for individual i), NAO[y] (NAO index value for each year y)

# initial values file requirements: z[t], etap, etaphi, etaPsi, etaBp, etaBPsi, b0, b1, mu.p[k], mu.Psi[k]

model {

# Hyper-priors on phi, Psi and p

mu.p ~ dnorm(0,0.667)

tau.p ~ dgamma(0.001,0.001)

### Need to put priors on the slope/intercept of NAO effect (b0, b1) instead of the mean (mu.phi)

b0 ~ dnorm(0, 0.667)

b1 ~ dnorm(0, 0.667) I(-2,2)

tau.phi ~ dgamma(0.001,0.001)

mu.Psi ~ dnorm(0,0.667)

tau.Psi ~ dgamma(0.001,0.001)

# calculate hierarchical means for year-variant parameters: reverse log-transform of hyperpriors

mean.p <- exp(mu.p) / (1+exp(mu.p))

mean.Psi <- exp(mu.Psi) / (1+exp(mu.Psi))

# Bayes predictive distributions for year-variant parameters (p & Psi)

logit(Bpd.p) <- etaBp

etaBp ~ dnorm(mu.p, tau.p)

logit(Bpd.Psi) <- etaBPsi

etaBPsi ~ dnorm(mu.Psi, tau.Psi)

# loop over years

for (y in 1:Y){

# Priors on p, phi & Psi in each state (with specific stopover constraints and NAO effect on phi)

p[y,1] <- 0

logit(p[y,2]) <- etap[y]

etap[y] ~ dnorm(mu.p, tau.p) I(-4,4)

p[y,3] <- 0

p[y,K+1] <- 0

phi[y,1] <- 1

logit(phi[y,2]) <- etaphi[y]

mu.phi[y] <- b0 + b1*(NAO[y]) # NAO effect on (1-departure probability)

etaphi[y] ~ dnorm(mu.phi[y], tau.phi) I(-4,4)

phi[y,3] <- 0

Psi[y,1,1] <- 0

logit(Psi[y,1,2]) <- etaPsi[y]

etaPsi[y] ~ dnorm(mu.Psi, tau.Psi) I(-4,4)

Psi[y,1,3] <- 1-Psi[y,1,2] # transient probability

Psi[y,2,1] <- 0

Psi[y,2,2] <- 1

Psi[y,2,3] <- 0

Psi[y,3,1] <- 0

Psi[y,3,2] <- 0

Psi[y,3,3] <- 1

# defining "transition" probability q (surviving and moving in one time step) among states

q[y,K+1, K+1] <- 1

for (k in 1:K){

q[y,K+1, k] <- 0

q[y,k, K+1] <- 1 - phi[y,k]

for (j in 1:K){

q[y,k,j] <- phi[y,k] * Psi[y,k,j]

} # close j loop

} # close k loop

# defining likelihoods and relationships between data and process

for (i in Bidx[y]:(Bidx[y+1]-1)){

for (t in (idx[i]+c[i]):(idx[i+1]-1)){

# Process model

z[t] ~ dcat(q[y,z[t-1],1:K+1])

# Observation model

w[t] ~ dbern(p[y,z[t]])

} # close t loop

} # close i loop

} # close y loop

} # end of model

Appendix 3 – Annual estimates of transience and departure at stopover for eight species of migrants at Long Point, Ontario.

Hermit thrush (Catharus guttatus; HETH); temperate migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

Ruby-crowned kinglet (Regulus calendula; RCKI); temperate migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

Dark-eyed junco (Junco hyemalis; DEJU); temperate migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

White-throated sparrow (Zonotrichia albicollis; WTSP); temperate migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

American redstart (Setophaga ruticilla; AMRE); tropical migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

Black-throated blue warbler (Dendroica caerulescens; BTBW); tropical migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

Magnolia warbler (Dendroica magnolia; MAWA); tropical migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.

Swainson’s thrush (Catharus ustulatus; SWTH); tropical migrant - spring (top) and fall (bottom) estimates of transience (left) and departure (right) at Long Point, Ontario from 1987-2007 (missing values for 1993, 2003), and hierarchical mean (Hm), from a hierarchical Bayes multi-state mark-recapture model.